#-------------------------------------------------------------------------------------------------------------
        # Edited for Monthly Challenge Start Up.
        # Originally edited by Sing and Helix in 2010
        # Original was Lonestar's startup
        #-------------------------------------------------------------------------------------------------------------
        # Edit your info into these settings
        # Game settings
        setVar $cname "Your Corp"
        setVar $cpass "Your Corp Pass"
	setVar $SSChan 12345   #Your ss channel

        #-------------------------------------------------------------------------------------------------------------
        # Other stuff
	setVar $TagLine			"Monthly Challenge Startup"
	setVar $CURENT_VERSION	        "1.05"
	setVar $maxFigAttack	        999
	setVar $LoginName		""
	setVar $GameAlias		""
	setVar $PassWord		""
	setVar $GameLetter       	""
	setVar $CorpName		""
	setVar $CorpPW			""
	setVar $RunScript		""
	setVar $Mow			FALSE
	setVar $DOOR_NUMBER		1
	setVar $MAKE_CORP		FALSE
        setVar $ECHOINTERVAL            900
	setVar $GRAB FALSE
        setVar $doRelog TRUE
        saveVar $doRelog
        saveVar $ECHOINTERVAL

        # Set a random door number between 2 and 5
        getRnd $SDDoor 2 5
        setVar $DOOR_NUMBER $SDDoor
	if (PASSWORD <> "")
		setVar $PassWord PASSWORD
	end
	if (LOGINNAME <> "")
		setVar $LoginName LOGINNAME
		setVar $GameAlias LOGINNAME
	end
	if (GAME <> "")
		setVar $GameLetter GAME
	end

	#getRnd $SSChan 100 60000

	if (CONNECTED)
		echo ANSI_15 & "**Must Not Be Connected To Server!**"
		halt
	end

        setVar $DOOR_NUMBER $SDDoor
	setVar $Mow TRUE
	:Menu_Top
	echo #27 & "[2J"
	echo "**"
	Echo ("    "&ANSI_15&#196&#196&ANSI_7&#196&ANSI_8&#196&ANSI_8&#196&ANSI_8&#196&ANSI_8&#196&ANSI_8&#196&ANSI_8&#196&ANSI_8&#196&ANSI_8&#196&ANSI_8&#196&ANSI_8&#196&ANSI_8&#196&ANSI_8&#196&ANSI_8&#196&ANSI_8&#196&ANSI_8&#196&ANSI_8&#196&ANSI_8&#196&ANSI_8&#196&ANSI_8&#196&ANSI_8&#196&ANSI_8&#196&ANSI_8&#196&ANSI_8&#196&ANSI_8&#196&ANSI_8&#196&ANSI_8&#196&ANSI_8&#196&ANSI_7&#196&ANSI_15&#196&#196)
	echo ANSI_14 & "*          " & $TagLine
	echo ANSI_8 & "*              Version " & $CURENT_VERSION
	echo ANSI_15 & "*       TWX Info: " & ANSI_14 & GAMENAME & "*"
	Echo ("    "&ANSI_15&#196&#196&ANSI_7&#196&ANSI_8&#196&ANSI_8&#196&ANSI_8&#196&ANSI_8&#196&ANSI_8&#196&ANSI_8&#196&ANSI_8&#196&ANSI_8&#196&ANSI_8&#196&ANSI_8&#196&ANSI_8&#196&ANSI_8&#196&ANSI_8&#196&ANSI_8&#196&ANSI_8&#196&ANSI_8&#196&ANSI_8&#196&ANSI_8&#196&ANSI_8&#196&ANSI_8&#196&ANSI_8&#196&ANSI_8&#196&ANSI_8&#196&ANSI_8&#196&ANSI_8&#196&ANSI_8&#196&ANSI_8&#196&ANSI_7&#196&ANSI_15&#196&#196)
	echo ANSI_15&"*         Login Name    : " & ANSI_14 & $LoginName
	echo ANSI_15&"*   (A)   Game Alias    : " & ANSI_14 & $GameAlias
	echo ANSI_15&"*         PassWord      : " & ANSI_14 & $PassWord
	echo ANSI_15&"*         Game Letter   : " & ANSI_14 & $GameLetter
	echo ANSI_15&"*         SS Chan       : " & ANSI_14 & $SSChan
	echo ANSI_15&"*         Mow To Dock   : " & ANSI_14 & $SDDoor

        ECHO "*    " #27 "[1m" ANSI_4 #196 #196 #196 #196 #196 #196  #196 #196 #196 #196 #196 #196 #196 #196 #196 #196 #196 #196 #196 #196 #196 #196 #196 #196 #196 #196 #196 #196 #196 #196 #196 #196 #196
	echo ANSI_15&"*     X - Execute!    Q - Quit!"
	echo "**"

        :Input_Again
            getConsoleInput $selection SINGLEKEY
            upperCase $selection
        if ($selection = "X")
		goto :Lets_Get_It_On
        elseif ($selection = "A")
		getInput $selection	ANSI_15 & #27 & "[1A" & #27 & "[K" & ANSI_14 & "*Game Alias?"
		getlength $selection $len
		if ($len > 40)
			cutText $selection $selection 1 40
		end
		setvar $GameAlias $selection
	elseif ($selection = "Q")
		halt
	else
    	goto :Input_Again
	end
   	goto :Menu_Top

:Lets_Get_It_On
	if (($PassWord = "") OR ($LoginName = "") OR ($GameLetter = "") OR ($GameAlias = ""))
		echo ANSI_14 & "**DATA Missing" & ANSI_15 & " - Some or all Login Info Is Missing.**"
		halt
	end
	if (($MAKE_CORP) AND (($CorpName = "") OR ($CorpPW = "")))
		echo ANSI_14 & "**DATA Missing" & ANSI_15 & " - Some or all Corp Info Is Missing.**"
		halt
	end
	:Verifydelay
		killAllTriggers
		DISCONNECT
	:Disco_Test
                killtrigger Emancipate_CPU
		setDelayTrigger	Emancipate_CPU :Emancipate_CPU 3000
		pause
	:Emancipate_CPU
		killAllTriggers
		setTextTrigger ENTER :ENTER "Please enter your name (ENTER for none):"
		setDelayTrigger VerifyDelay :VerifyDelay 10000
   		CONNECT
		# if (CONNECTED <> TRUE)
		# 	Echo "**" & ANSI_14 & "Awaiting Connection!**"
		# 	goto :Disco_Test
		# end
		pause

	:ENTER
	send #8 & #8 & #8 & #8 & #8 & $LoginName & "*"
        waitFor " Game Server "
	killtrigger VerifyDelay
        killtrigger letter_delay
        setDelayTrigger letter_delay :letter_delay 3000
        pause
        :letter_delay
        killtrigger letter_delay
        send $GameLetter

    	killAllTriggers
    	setTextTrigger		Pause1		:Pause		"[Pause]"
    	setTextTrigger		Pause2		:Pause		"[Press Space or Enter to continue]"
    	setDelayTrigger		NoPause		:NoPause	20000
	Echo "**" & ANSI_14 & "Waiting 20 Seconds for a "&ANSI_5&"["&ANSI_6&"Pause"&ANSI_5&"]**"
	pause

	:NoPause
	killAllTriggers
	DISCONNECT
	goto :Verifydelay

    	:Pause
	killAllTriggers
    	send "*"
    	waitfor "Enter your choice:"
    	killAllTriggers
	setTextLineTrigger	NoName		:NoName			"Sorry, you cannot use the name "
	setTextLineTrigger	GameClosed1	:GameClosed		"I'm sorry, but this is a closed game."
	setTextLineTrigger	GameClosed2	:GameClosed		"www.tradewars.com                                   Epic Interactive Strategy"
    	setTextLineTrigger	GameClosed3	:GameClosed		"I'm sorry, but the game is in tournament mode and is no longer"
    	setTextLineTrigger	Damn_Planet	:Damn_Planet		"What do you want to name your home planet?"
    	setTextLineTrigger	NOALIASES	:NO_ALIAS		"What do you want to name your ship?"
	setTextTrigger	        ALIASES		:ALIAS			"Use (N)ew Name or (B)BS Name"
	setTextTrigger	        GoName		:GoName			" is what you want? "
	setTextTrigger		Phew		:Phew			"Command [TL"
        setTextTrigger          ughpause        :ughpause               "[Pause]"
	send "T***Y" & $PassWord & "*" & $PassWord & "*"
	pause

        :ughpause
        send " "
        killTrigger ughpause
        setTextTrigger          ughpause        :ughpause               "[Pause]"
        pause

	:NO_ALIAS
		killTrigger ALIASES
		killTrigger GameClosed1
		killTrigger GameClosed2
		killTrigger GameClosed3
		send ".*Y"
		pause
	:ALIAS
		killTrigger NOALIASES
		send "N" & $GameAlias & "*"
		pause
	:NoName
                killAllTriggers
                echo ANSI_12 & "**ERROR**"
                halt
	:GoName
                killTrigger NoName
                killTrigger NOALIASES
		killTrigger GameClosed1
		killTrigger GameClosed2
		killTrigger GameClosed3
		send "Y.*Y"
		pause
	:GameClosed
		killAllTriggers
		DISCONNECT
		setDelayTrigger  WhistleWhileYouWork	:WhistleWhileYouWork 1000
		pause
		:WhistleWhileYouWork
		goto :Lets_Get_It_On
	:Damn_Planet
		killTrigger GameClosed1
		killTrigger GameClosed2
		killTrigger GameClosed3
		send ".*  Q  "
		pause
	:Phew
		killAllTriggers
		if (($MAKE_CORP) AND (($CorpName <> "") OR ($CorpPW <> "")))
			send "*TM"&$CorpName&"*Y"&$CorpPW&"*YQCN4"&$SSChan&"*QQQQZN*^Q"
		else
			send "*CN4"&$SSChan&"*QQQZN*^Q"
		end
		setTextLineTrigger		AllDone		:AllDone ": ENDINTERROG"
		pause

    :AllDone
    	killAllTriggers
        gosub :fix_cn_settings
    	if ($Mow)
    		send "V"
    		waitOn "-=-=-=-  Current Stats for"
    		waiton "Command [TL="
			if ((STARDOCK = "0") OR (STARDOCK = ""))
				echo ("**" & ANSI_14 & "Cannot MOW To StarDock. It Appears to be Hidden.**")
				halt
			end
			send " c v 0 * y y q "
			setVar $To STARDOCK
			setVar $from CURRENTSECTOR
			gosub :Find_2nd_Door
			gosub :quikstats
        		gosub :getCourse
			setVar $j 1
			setVar $mow_to ""
			while ($j <= $courselength)
				setVar $mow_to ($mow_to & "  m " & $COURSE[$j] & "*  ")
				if (($COURSE[$j] > 10) AND ($COURSE[$j] <> STARDOCK))
					setVar $mow_to ($mow_to & "z a " & $maxFigAttack & "998877665544332211000*  *  ")
				end
				if (($JET) AND ($j = ($courselength - 1)))
					setVar $mow_to ($mow_to & " j y ")
				end
		    	add $j 1
		    end

			send ($mow_to & "^ Q  ")
			waitfor ": ENDINTERROG"
#------------------------Join the Corp and SellDown-----------------------------
			goto :JoinCorp
                        :ReturnLabel
                        gosub :quikstats

			if ($CURRENT_SECTOR = $TO)
		send " c v 0 * y y q "
    	    	if ($ALIGNMENT < 0)
					send "  P  S G Y G Q"
					waiton "You leave the Galactic Bank."
					send "/"
					waiton "<StarDock> Where to?"
               		echo ANSI_15 & "**Alignment Below Zero - Hiding On Dock!**"
               		halt
            	else
            		send "IVD"
               	end
			else
				send " N * /"
				waitfor "Command [TL"
				echo ANSI_15 & "**Whoops, Not At Dock!**"
				halt
			end
        else
        	send "CV*YYQIVD"
		end

		if ($RunScript <> "")
			Echo "****"&ANSI_14&"Starting Script: " &  ANSI_15 & $RunScript
			setDelayTrigger	WaitingForGaDoe		:WaitingForGaDoe	1000
			pause
			:WaitingForGaDoe
			killAllTriggers
			load $RunScript
		end
	halt

:getCourse
	killalltriggers
	setVar $sectors ""
	setTextLineTrigger sectorlinetrig :sectorsline " > "
	send "^f"&$From&"*"&$To&"*nq"
	pause
:sectorsline
	killAllTriggers
	setVar $line CURRENTLINE
	replacetext $line ">" " "
	striptext $line "("
	striptext $line ")"
	setVar $line $line&" "
	getWordPos $line $pos "So what's the point?"
	getWordPos $line $pos2 ": ENDINTERROG"
	getWordPos $line $pos3 "*** Error"

	if (($pos > 0) OR ($pos2 > 0))
		setVar $courseLength 0
		return
	end
	getWordPos $line $pos " sector "
	getWordPos $line $pos2 "TO"
	if (($pos <= 0) AND ($pos2 <= 0))
		setVar $sectors $sectors & " " & $line
	end
	getWordPos $line $pos " "&$To&" "
	getWordPos $line $pos2 "("&$To&")"
	getWordPos $line $pos3 "TO"
	if ((($pos > 0) OR ($pos2 > 0)) AND ($pos3 <= 0))
		goto :gotSectors
	else
		setTextLineTrigger sectorlinetrig :sectorsline " > "
		setTextLineTrigger sectorlinetrig2 :sectorsline " "&$To&" "
		setTextLineTrigger sectorlinetrig3 :sectorsline " "&$To
		setTextLineTrigger sectorlinetrig4 :sectorsline "("&$To&")"
		setTextLineTrigger donePath :sectorsline "So what's the point?"
		setTextLineTrigger donePath2 :sectorsline ": ENDINTERROG"
	end
	pause

:gotSectors
	killAllTriggers
	setVar $COURSE 0
	setVar $sectors $sectors&" :::"
	setVar $courseLength 0
	setVar $index 1
	:keepGoing
	if ($sectors = " FM     :::")
		return
	end
	getWord $sectors $TEMPO $index
	while ($TEMPO <> ":::")
		if ($TEMPO <> "FM") AND ($TEMPO <> $From)
			add $courseLength 1
			setVar $COURSE[$courseLength] $TEMPO
		end
		add $index 1
		getWord $sectors $TEMPO $index
	end
	return

:noPath
	killAllTriggers
	goSub :showTitle
	goto :wait

:quikstats
	setVar $CORP 0
	SetVar $CURRENT_PROMPT 		"Undefined"
	killtrigger noprompt
	killtrigger prompt1
	killtrigger prompt2
	killtrigger prompt3
	killtrigger prompt4
	killtrigger statlinetrig
	killtrigger getLine2
	setTextTrigger 		prompt1 	:allPrompts 		"(?="
	setTextLineTrigger 	prompt2 	:secondaryPrompts 	"(?)"
	setTextLineTrigger 	statlinetrig 	:statStart 		#179
	setTextTrigger		prompt3         :terraPrompts		"Do you wish to (L)eave or (T)ake Colonists?"
	setTextTrigger		prompt4         :terraPrompts		"How many groups of Colonists do you want to take ("
	send "^Q/"
	pause

	:allPrompts
		getWord currentansiline $checkPrompt 1
		getWord currentline $tempPrompt 1
		getWordPos $checkPrompt $pos ""
		if ($pos > 0)
			SetVar $CURRENT_PROMPT $tempPrompt
		end
		setTextLineTrigger prompt1 :allPrompts "(?="
		pause
	:secondaryPrompts
		getWord currentansiline $checkPrompt 1
		getWord currentline $tempPrompt 1
		getWordPos $checkPrompt $pos ""
		if ($pos > 0)
			SetVar $CURRENT_PROMPT $tempPrompt
		end
		setTextLineTrigger prompt2 :secondaryPrompts "(?)"
		pause
	:terraPrompts
		killtrigger prompt3
		killtrigger prompt4
		getWord currentansiline $checkPrompt 1
		getWordPos $checkPrompt $pos ""
		if ($pos > 0)
			SetVar $CURRENT_PROMPT "Terra"
		end
		setTextTrigger		prompt3         :terraPrompts		"Do you wish to (L)eave or (T)ake Colonists?"
		setTextTrigger		prompt4         :terraPrompts		"How many groups of Colonists do you want to take ("
		pause
	:statStart
		killtrigger prompt1
		killtrigger prompt2
		killtrigger prompt3
		killtrigger prompt4
		killtrigger noprompt
		SetVar $stats ""
		SetVar $wordy ""
	:statsline
		killtrigger statlinetrig
		killtrigger getLine2
		SetVar $line2 CURRENTLINE
		replacetext $line2 #179 " "
		striptext $line2 ","
		SetVar $stats $stats & $line2
		getWordPos $line2 $pos "Ship"
		if ($pos > 0)
			goto :gotStats
		else
			setTextLineTrigger getLine2 :statsline
			pause
		end

	:gotStats
		SetVar $stats $stats & " @@@"

		SetVar $current_word 0
		while ($wordy <> "@@@")
			if ($wordy = "Sect")
				getWord $stats $CURRENT_SECTOR   	($current_word + 1)
			elseif ($wordy = "Turns")
				getWord $stats $TURNS  				($current_word + 1)
			elseif ($wordy = "Creds")
				getWord $stats $CREDITS  			($current_word + 1)
			elseif ($wordy = "Figs")
				getWord $stats $FIGHTERS   			($current_word + 1)
			elseif ($wordy = "Shlds")
				getWord $stats $SHIELDS  			($current_word + 1)
			elseif ($wordy = "Hlds")
				getWord $stats $TOTAL_HOLDS   		($current_word + 1)
			elseif ($wordy = "Ore")
				getWord $stats $ORE_HOLDS    		($current_word + 1)
			elseif ($wordy = "Org")
				getWord $stats $ORGANIC_HOLDS    	($current_word + 1)
			elseif ($wordy = "Equ")
				getWord $stats $EQUIPMENT_HOLDS    	($current_word + 1)
			elseif ($wordy = "Col")
				getWord $stats $COLONIST_HOLDS    	($current_word + 1)
			elseif ($wordy = "Phot")
				getWord $stats $PHOTONS   			($current_word + 1)
			elseif ($wordy = "Armd")
				getWord $stats $ARMIDS   			($current_word + 1)
			elseif ($wordy = "Lmpt")
				getWord $stats $LIMPETS   			($current_word + 1)
			elseif ($wordy = "GTorp")
				getWord $stats $GENESIS 	 		($current_word + 1)
			elseif ($wordy = "TWarp")
				getWord $stats $TWARP_TYPE  		($current_word + 1)
			elseif ($wordy = "Clks")
				getWord $stats $CLOAKS   			($current_word + 1)
			elseif ($wordy = "Beacns")
				getWord $stats $BEACONS 			($current_word + 1)
			elseif ($wordy = "AtmDt")
				getWord $stats $ATOMIC  			($current_word + 1)
			elseif ($wordy = "Corbo")
				getWord $stats $CORBO   			($current_word + 1)
			elseif ($wordy = "EPrb")
				getWord $stats $EPROBES 	  		($current_word + 1)
			elseif ($wordy = "MDis")
				getWord $stats $MINE_DISRUPTORS   	($current_word + 1)
			elseif ($wordy = "PsPrb")
				getWord $stats $PSYCHIC_PROBE  		($current_word + 1)
			elseif ($wordy = "PlScn")
				getWord $stats $PLANET_SCANNER  	($current_word + 1)
			elseif ($wordy = "LRS")
				getWord $stats $SCAN_TYPE    		($current_word + 1)
			elseif ($wordy = "Aln")
				getWord $stats $ALIGNMENT    		($current_word + 1)
			elseif ($wordy = "Exp")
				getWord $stats $EXPERIENCE    		($current_word + 1)
			elseif ($wordy = "Corp")
				getWord $stats $CORP  	 		($current_word + 1)
			elseif ($wordy = "Ship")
				getWord $stats $SHIP_NUMBER   		($current_word + 1)
			end
			add $current_word 1
			getWord $stats $wordy $current_word
		end
	:doneQuikstats
		killtrigger prompt1
		killtrigger prompt2
		killtrigger prompt3
		killtrigger prompt4
		killtrigger statlinetrig
		killtrigger getLine2
	return

:Find_2nd_Door
	if ($DOOR_NUMBER > 1)
		setVar $i 1
		send "C"
		while ($i < $DOOR_NUMBER)
			gosub :getCourse
			setVar $k 2
			while ($k <= $courselength)
				if ($COURSE[$k] = $TO)
					setVar $adj $COURSE[($k - 1)]
					send ("V" & $adj & "*")
				end
		    	add $k 1
			end
			add $i 1
		end
		send "Q"
		waitfor "<Computer deactivated>"
	end
	return

:JoinCorp
# -----------------------------------------------------------------------------

  setVar $cagnd "Join Corp"
  gosub :handle_corping
  
  # -----------------------------------------------------------------------------
  halt
  # -----------------------------------------------------------------------------
  
  :handle_corping

  # Are currently on a corp?
  gosub :quikstats
  if ($CORP > 0)
      goto :continue_past_corp_join
  end

  # Nope
  setVar $join_count 1
  
  :get_the_corp_list
  setVar $find_corp $cname
  upperCase $find_corp
  setVar $found_corp FALSE
  send "tdl*"
  waitFor "< T h e   C o r p o r a t e   R e g i s t e r >"
  waitFor "Corp Number"
  killtrigger corpline
  setTextLineTrigger corpline :corpline ""
  pause
  
  :corpline
  killtrigger corpline
  getWord CURRENTLINE $firstword 1
  if ($firstword = "Corporate") OR ($firstword = "Command")
       goto :end_of_corp_scan
  end
  isNumber $result $firstword
  if ($result > 0)
       setVar $line CURRENTLINE
       upperCase $line
       getWordPos $line $pos $find_corp
       if ($pos > 1)
            setVar $found_corp  TRUE
            setVar $corp_number $firstword
            goto :end_of_corp_scan
       end
  end
  setTextLineTrigger corpline :corpline ""
  pause
  
  :end_of_corp_scan
  killtrigger corpline
  if ($found_corp = TRUE)
       send "tj" & $corp_number & "*" & $cpass & "**"
       send "c u y o * c q "
       goto :continue_past_corp_join
  else
       if ($cagnd = "Make New Corp")
            send "tm" & $cname & "*y" & $cpass & "*y*"
            send "c u y o * c q "
            goto :continue_past_corp_join
       else
            killtrigger wait_for_corp
            setDelayTrigger wait_for_corp :wait_for_corp 3000
            send "'Corp not formed! Attempt #" & $join_count & ". Retrying in 3 seconds...*"
            pause
            :wait_for_corp
            killtrigger wait_for_corp
            add $join_count 1
            if ($join_count > 20)
                 send "'Couldn't join corp! Continuing on...*"
                 goto :continue_past_corp_join
            else
                 goto :get_the_corp_list
            end
       end
  end

:continue_past_corp_join
send "p s s b y ybycScout**qqqq*"
# Echo "Buy Scout Here!"
goto :ReturnLabel
halt

# --------------------------------------------------------------------------------

:fix_cn_settings
     send " qqqqqqza99999* "
     waitFor "Command [TL="

     setVar $cn_string ""
     send "CN"

     killtrigger fix_ansi
     killtrigger fix_anim
     killtrigger fix_page
     killtrigger setsschn
     killtrigger fix_hail
     killtrigger fix_msgs
     killtrigger fix_abrt
     killtrigger fix_disp
     killtrigger fix_paus
     killtrigger fix_flee
     killtrigger fix_sets
     SetTextLineTrigger fix_ansi :fix_ansi "(1) ANSI graphics            - Off"
     SetTextLineTrigger fix_anim :fix_anim "(2) Animation display        - On"
     SetTextLineTrigger fix_page :fix_page "(3) Page on messages         - On"
     SetTextLineTrigger setsschn :setsschn "(4) Sub-space radio channel"
     SetTextLineTrigger fix_hail :fix_hail "(6) Receive private hails    - No"
     SetTextLineTrigger fix_msgs :fix_msgs "(7) Silence ALL messages     - Yes"
     SetTextLineTrigger fix_abrt :fix_abrt "(9) Abort display on keys    - ALL KEYS"
     SetTextLineTrigger fix_disp :fix_disp "(A) Message Display Mode     - Long"
     SetTextLineTrigger fix_paus :fix_paus "(B) Screen Pauses            - Yes"
     SetTextLineTrigger fix_flee :fix_flee "(C) Online Auto Flee         - On"
     setTextTrigger     fix_sets :fix_sets "Settings command (?=Help)"
     pause
     return

     :fix_ansi
     setVar $cn_string $cn_string & "1"
     pause

     :fix_anim
     setVar $cn_string $cn_string & "2"
     pause

     :fix_page
     setVar $cn_string $cn_string & "3"
     pause

     :setsschn
     getWord CURRENTLINE $sschan 6
     if ($sschan = 0)
          getRnd $newchan 5000 60000
          setVar $cn_string $cn_string & "4" & $newchan & "*"
     end
     pause

     :fix_hail
     setVar $cn_string $cn_string & "6"
     pause

     :fix_msgs
     setVar $cn_string $cn_string & "7"
     pause

     :fix_abrt
     setVar $cn_string $cn_string & "9"
     pause

     :fix_disp
     setVar $cn_string $cn_string & "A"
     pause

     :fix_paus
     setVar $cn_string $cn_string & "B"
     pause

     :fix_flee
     setVar $cn_string $cn_string & "C"
     pause

     :fix_sets
     killtrigger fix_ansi
     killtrigger fix_anim
     killtrigger fix_page
     killtrigger setsschn
     killtrigger fix_hail
     killtrigger fix_msgs
     killtrigger fix_abrt
     killtrigger fix_disp
     killtrigger fix_paus
     killtrigger fix_flee
     killtrigger fix_sets
     setVar $cn_string $cn_string & "QQ"
     send $cn_string
     waitFor "<Computer deactivated>"
return

# --------------------------------------------------------------------------------