#
#  Lonestar's Planet Lister (TL) modified by Astrochimp
#  Changes to Lonestar's version  
#       - make it bottable 
#              remove menus; 
#              change most error messages to go via subspace; 
#              load some bot variables
#              add bot parameters for ss, cit, write
#       - remove complicated filter logic; filter is now only available as 'cit' option
#       - fixed: formatting problem caused by planets with no cits (use "-" instead of "-1")
#       - fixed: when planet has a lot of shields, shields shows as zero.

logging off
loadVar $bot_name
loadVar $unlimitedGame
loadVar $bot_turn_limit
loadVar $user_command_line
loadVar $parm1
loadVar $parm2
loadVar $parm3
loadVar $parm4
loadVar $parm5
loadVar $parm6
loadVar $parm7
loadVar $parm8
loadVar $stardock
loadVar $backdoor
loadvar $LIMPET_COST
loadvar $ARMID_COST
loadVar $LIMPET_REMOVAL_COST
loadvar $password
loadVar $port_max
loadVar $ptradesetting
loadVar $ARMID_COUNT_FILE 
loadVar $ARMID_FILE 

# ========================================= TL ======================================================			
if (CONNECTED = FALSE)
	Echo "**" & ANSI_12 & "Must Be Connected**"
	halt
end

#Get input parameters
if ($parm1 = "help")
  # send help string
  send "'* Usage: TL {ss} {cit} {write}*"
  send   "            {ss}    - Send results over subspace*"
  send   "            {cit}   - List planets with citadels only*"
  send   "            {write} - Write results to file GAMENAME & _TL.txt*"
  send   "            *"
  send   "     Author:           Astrochimp*"
  send   "     Version:          0.9*"
  send   "     Original author:  Lonestar*"
  send "*"
  halt
else
  gosub :quikstats

  if ($CURRENT_PROMPT <> "Command") AND ($CURRENT_PROMPT <> "Citadel")
    echo "* current prompt:  " & $CURRENT_PROMPT & "*"
    send "'{" $bot_name "} - TL must be run from the Command Prompt or Citadel Prompt*"
    halt
  end

  #set output method
  getWordPos $user_command_line $pos "ss"
  if ($pos > 0)
    setVar $tl_ss TRUE
  else
    setVar $tl_ss FALSE
  end
  setVar $pos 0
  getWordPos $user_command_line $pos "cit"
  if ($pos > 0)
    setVar $CITONLY TRUE
  else
    setVar $CITONLY FALSE
  end
  setVar $pos 0
  getWordPos $user_command_line $pos "write"
  if ($pos > 0)
    setVar $WRITE TRUE
  else
    setVar $WRITE FALSE
  end
end		

setVar $HR1		("*         " & ANSI_15 & #196 & #196 & ANSI_7 & #196 & #196 & #196 & #196& #196& #196& #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & ANSI_7 & #196 & ANSI_15 & #196 & #196)
setVar $HR2		("*                   " & ANSI_15 & #196 & #196 & ANSI_7 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & #196 & ANSI_7 & #196 & ANSI_15 & #196 & #196)
setVar $VERSION "0.1"

setVar $FName GAMENAME & "_TL" & ".txt"

:_START_
gosub :quikstats
if ($CURRENT_PROMPT = "Command")
	send "V"
elseif ($CURRENT_PROMPT = "Citadel")
	send "qd"
	waiton "Planet #"
	GetWord CURRENTLINE $PLANET 2
	stripText $PLANET " "
	stripText $PLANET "#"
	send "QVL "&$PLANET&"*C"
else
	Echo "**" & ANSI_12 & "Please Start From Command Or Citadel Prompt**"
	halt
end
setTextLineTrigger	GAME_MAX_PLANETS 	:GAME_MAX_PLANETS	"Maximum players"
setTextLineTrigger	GAME_MAX_PerSECTOR	:GAME_MAX_PerSECTOR "The Maximum number of Planets per sector:"
setTextLineTrigger	GAME_MAX_DONE		:GAME_MAX_DONE		"-=-=-=-  Current Stats"
pause
:GAME_MAX_PerSECTOR
gettext CURRENTLINE $MAX_PLANET_SEC "sector:" ",  Traders"
stripText $MAX_PLANET_SEC " "
stripText $MAX_PLANET_SEC ","
pause
:GAME_MAX_PLANETS
getText CURRENTLINE $MAX_PLANETS "planets" "."
stripText $MAX_PLANETS " "
stripText $MAX_PLANETS ","
pause
:GAME_MAX_DONE
killAllTriggers
if ($CURRENT_PROMPT = "Command")
	waiton "Command"
elseif ($CURRENT_PROMPT = "Citadel")
	waiton "Citadel"
end
setVar $MAX_ATTRIBUTES	10
setvar $MAXIMUM_per_SECTOR 20
setArray $XXX $MAX_PLANETS $MAXIMUM_per_SECTOR $MAX_ATTRIBUTES
#   Attribute Constants   $MAX_PLANET_SEC
setVar $Cols_Ore		1
setVar $Cols_Org		2
setVar $Cols_Equ		3
setVar $Pro_Ore			4
setVar $Pro_Org			5
setVar $Pro_Equ			6
setVar $Tot_Fig			7
setVar $Tot_Cred		8
setVar $Tot_Shields		9
setVar $P_Class			10
setVar $COUNT			0

setVar $Line 1
setTextLineTrigger	Prob_1	:PROB	"You're not on a team!"
setTextLineTrigger	Prob_2	:PROB	"No Planets claimed"
if ($CURRENT_PROMPT = "Command")
	send "TLQ"
else
	send "XLQ"
end
setDelayTrigger	Time_OUT	:Time_OUT 20000
waiton "===================================================================="
setTextLineTrigger	Done	:Done	"======   ============  ==== ==== ===="
setTextLineTrigger	Line	:Line
pause
:Time_OUT
killAllTriggers
send "'{" $bot_name "} - Planet Listing Timed Out*"
#Echo "**" & ANSI_12 & "Planet Listing Timed Out**"
halt
:PROB
killAllTriggers
send "'{" $bot_name "} - Planet Listing Timed Out*"
#Echo "**" & ANSI_12 & "Problem: Must Be On A Corp, and Have Corp Planets To List!**"
halt
:Line
SetVar $TEMP CURRENTLINE
if ($Line = 1)
	add $Line 1
	getWord $TEMP $SECT 1
	isNumber $tst $SECT
	if ($tst)
		if ($SECT <> 0)
			getLength $TEMP $len
			cutText $TEMP $LEVEL ($len - 1) $len
			isNumber $tst $LEVEL
			if ($tst = 0)
				#setVar $LEVEL "-1"
        setVar $LEVEL "-"
			end
		end
	end
	cutText $TEMP $CLASS 47 1
elseif ($Line = 2)
	Subtract $Line 1
	add $COUNT 1
	if ($SECT <> 0)
		setVar $idx 1
		while ($idx <= $MAX_PLANETS)
			if ($XXX[$idx] = $SECT)
				setVar $idy 1
				while ($idy <= $MAXIMUM_per_SECTOR)
					if ($XXX[$idx][$idy] = 0)
						setVar $XXX[$idx][$idy] $LEVEL
						gosub :PARSE
						goto :NEXT
					end
                	add $idy 1
				end
				goto :NEXT
            elseif ($XXX[$idx] = 0)
            	setVar $idy 1
				setVar $XXX[$idx] $SECT
				setVar $XXX[$idx][$idy] $LEVEL
				gosub :PARSE
				goto :NEXT
            end
        	add $idx 1
		end
	end
end
:NEXT
setTextLineTrigger	Line	:Line
pause
:Done
killAllTriggers
if ($CURRENT_PROMPT = "Command")
waiton "Command [TL"
else
waiton "Citadel command"
end
setVar $idx 1
setVar $STR_DATA ""
setVar $cORE 0
setVar $cORG 0
setVar $cEQU 0
setVar $pORE 0
setVar $pORG 0
setVar $pEQU 0
setVar $pFIG 0
setVar $PCRE 0

while ($idx <= $MAX_PLANETS)
	if ($XXX[$idx] <> 0)
		setVar $STR_DATA ($STR_DATA & "*" & ANSI_15 & " Sector"&ANSI_14&": " &ANSI_7& $XXX[$IDX])
		setVar $DEST $XXX[$IDX]
		gosub :SECTOR_DATA
		setVar $STR_DATA ($STR_DATA & $SECTOR_DATA_STR)
		setVar $idy 1
		while ($idy <= $MAXIMUM_per_SECTOR)
			if ($XXX[$idx][$idy] <> 0)
				gosub :SHOW_PLANET
				if ($SHOW)
				setVar $STR_DATA ($STR_DATA & "*"&ANSI_15&"  Lvl"&ANSI_14&": " &ANSI_7& $XXX[$idx][$idy] & ANSI_9 & $XXX[$idx][$idy][$P_Class] & " ")
				setVar $STR $XXX[$idx][$idy][$Tot_Shields]
				gosub :PAD
				setVar $STR_DATA ($STR_DATA & ANSI_15 & " " & $PAD & $XXX[$idx][$idy][$Tot_Shields])
				#Colonist in Fuel ORE
				setVar $STR $XXX[$idx][$idy][$Cols_Ore]
				gosub :PAD
				gosub :NUMERIZE
				add $cORE $STR
				setVar $STR_DATA ($STR_DATA & " " & ANSI_7 & $PAD & $XXX[$idx][$idy][$Cols_Ore])
				#Colonists in Organics
				setVar $STR $XXX[$idx][$idy][$Cols_Org]
				gosub :PAD
				gosub :NUMERIZE
				setVar $STR_DATA ($STR_DATA & " " & ANSI_8 & $PAD & $XXX[$idx][$idy][$Cols_Org])
				add $cORG $STR
				#Colonists in Equipment
				setVar $STR $XXX[$idx][$idy][$Cols_Equ]
				gosub :PAD
				gosub :NUMERIZE
				setVar $STR_DATA ($STR_DATA & " " & ANSI_7 & $PAD & $XXX[$idx][$idy][$Cols_Equ])
				add $cEQU $STR
				#Production in Fuel ORE
				setVar $STR $XXX[$idx][$idy][$Pro_Ore]
				gosub :PAD
				gosub :NUMERIZE
				setVar $STR_DATA ($STR_DATA & " " & ANSI_14 & $PAD & $XXX[$idx][$idy][$Pro_Ore])
				add $pORE $STR
				#Production in Organics
				setVar $STR $XXX[$idx][$idy][$Pro_Org]
				gosub :PAD
				gosub :NUMERIZE
				setVar $STR_DATA ($STR_DATA & " " & ANSI_6 & $PAD & $XXX[$idx][$idy][$Pro_Org])
				add $pORG $STR
				#Production in Equipment
				setVar $STR $XXX[$idx][$idy][$Pro_Equ]
				gosub :PAD
				gosub :NUMERIZE
				setVar $STR_DATA ($STR_DATA & " " & ANSI_14 & $PAD & $XXX[$idx][$idy][$Pro_Equ])
				add $pEQU $STR
				#Production in Fighters
				setVar $STR $XXX[$idx][$idy][$Tot_Fig]
				gosub :PAD
				gosub :NUMERIZE
				setVar $STR_DATA ($STR_DATA & " " & ANSI_15 & $PAD & $XXX[$idx][$idy][$Tot_Fig])
				add $pFIG $STR
				#Production in Denero, Mula, Bread, Cash, Dollars, Pessos.. etc
				setVar $STR $XXX[$idx][$idy][$Tot_Cred]
				gosub :PAD
				gosub :NUMERIZE
				setVar $STR_DATA ($STR_DATA & " " & ANSI_12 & $PAD & $XXX[$idx][$idy][$Tot_Cred])
				if ($STR <> "-")
					add $pCRE $STR
				end
				end
			end
			add $idy 1
		end
		setVar $STR_DATA ($STR_DATA & $HR2)
	end
	add $idx 1
end

setVar $STR_DATA $HR1 & $STR_DATA
setVar $STR_DATA ANSI_15 & "            SHLD   "&ANSI_7&"ORE   "&ANSI_8&"ORG   "&ANSI_7&"EQU   "&ANSI_14&"ORE   "&ANSI_14&"ORG   "&ANSI_14&"EQU  "&ANSI_15&"FIGS "&ANSI_12&"CREDS" & $STR_DATA
setVar $STR_DATA ANSI_7 & "                   Colonist Levels   Product Amounts*" & $STR_DATA
if ($CITONLY = TRUE)
  setVar $STR_DATA ANSI_15 & "                     AC's LS Corporate Citadel List*" & $STR_DATA
else
  setVar $STR_DATA ANSI_15 & "                     AC's LS Corporate Planet List*" & $STR_DATA
end

setVar $STR $cORE
gosub :ABREVIATE
gosub :PAD
setVar $STR_DATA $STR_DATA & "*"&ANSI_15&"   Grand Totals: " & ANSI_7 & $PAD & $STR & " "
setVar $STR $cORG
gosub :ABREVIATE
gosub :PAD
setVar $STR_DATA $STR_DATA & ANSI_8 & $PAD & $STR & " "  
setVar $STR $cEQU
gosub :ABREVIATE
gosub :PAD
setVar $STR_DATA $STR_DATA & ANSI_7 & $PAD & $STR & " "
setVar $STR $pORE
gosub :ABREVIATE
gosub :PAD
setVar $STR_DATA $STR_DATA & ANSI_14 & $PAD & $STR & " "
setVar $STR $pORG
gosub :ABREVIATE
gosub :PAD
setVar $STR_DATA $STR_DATA & ANSI_6 & $PAD & $STR & " "
setVar $STR $pEQU
gosub :ABREVIATE
gosub :PAD
setVar $STR_DATA $STR_DATA & ANSI_14 & $PAD & $STR & " "
setVar $STR $pFIG
gosub :ABREVIATE
gosub :PAD
setVar $STR_DATA $STR_DATA & ANSI_15 & $PAD & $STR & " "
setVar $STR $PCRE
gosub :ABREVIATE
gosub :PAD
setVar $STR_DATA $STR_DATA & ANSI_12 & $PAD & $STR & " "

setVar $STR_DATA $STR_DATA & $HR1 & "*"
setVar $STR_DATA $STR_DATA & ANSI_15 & "            SHLD   "&ANSI_7&"ORE   "&ANSI_8&"ORG   "&ANSI_7&"EQU   "&ANSI_14&"ORE   "&ANSI_14&"ORG   "&ANSI_14&"EQU  "&ANSI_15&"FIGS "&ANSI_12&"CREDS*"
setVar $STR_DATA $STR_DATA &  ANSI_7 & "                   Colonist Levels   Product Amounts*"
setVar $STR_DATA $STR_DATA &  "*"

if ($tl_ss = FALSE)  

  echo "***"
  echo $STR_DATA
 
  send "'{" & $BOT_NAME & "} - Planets listed locally.  Use tl ss to send list via subspace.*"
else
# output goes to ss
  replaceText $STR_DATA  ANSI_1 ""
	replaceText $STR_DATA  ANSI_2 ""
	replaceText $STR_DATA  ANSI_3 ""
	replaceText $STR_DATA  ANSI_4 ""
	replaceText $STR_DATA  ANSI_5 ""
	replaceText $STR_DATA  ANSI_6 ""
	replaceText $STR_DATA  ANSI_7 ""
	replaceText $STR_DATA  ANSI_8 ""
	replaceText $STR_DATA  ANSI_9 ""
	replaceText $STR_DATA  ANSI_10 ""
	replaceText $STR_DATA  ANSI_11 ""
	replaceText $STR_DATA  ANSI_12 ""
	replaceText $STR_DATA  ANSI_13 ""
	replaceText $STR_DATA  ANSI_14 ""
	replaceText $STR_DATA  ANSI_15 ""
	replaceText $STR_DATA #196 "-"
	#replaceText $STR_DATA #13 (#13 & #10)
  replaceText $STR_DATA #13 "*"
  replaceText $STR_DATA "**" "*"
  #setVar $STR_DATA $STR_DATA & "*            SHLD   ORE   ORG   EQU   ORE   ORG   EQU  FIGS CREDS*"
  
  #setVar $STR_DATA $STR_DATA & "*"
  
  send "'*"
  send " *"
  send $STR_DATA & "*"
end

if ($WRITE)
echo "*** WRITE " & $FName & " ***"
	replaceText $STR_DATA  ANSI_1 ""
	replaceText $STR_DATA  ANSI_2 ""
	replaceText $STR_DATA  ANSI_3 ""
	replaceText $STR_DATA  ANSI_4 ""
	replaceText $STR_DATA  ANSI_5 ""
	replaceText $STR_DATA  ANSI_6 ""
	replaceText $STR_DATA  ANSI_7 ""
	replaceText $STR_DATA  ANSI_8 ""
	replaceText $STR_DATA  ANSI_9 ""
	replaceText $STR_DATA  ANSI_10 ""
	replaceText $STR_DATA  ANSI_11 ""
	replaceText $STR_DATA  ANSI_12 ""
	replaceText $STR_DATA  ANSI_13 ""
	replaceText $STR_DATA  ANSI_14 ""
	replaceText $STR_DATA  ANSI_15 ""
	replaceText $STR_DATA #196 "-"
	replaceText $STR_DATA #13 (#13 & #10)
	delete $FName
	write $FName $STR_DATA
end

#goto :_MENU_
#send "*"
halt


:ABREVIATE
	getLength $STR $LEN
	if ($LEN = 7) OR ($LEN = 8) OR ($LEN = 9)
		cutText $STR $STR 1 ($LEN - 6)
		setVar $STR ($STR & "M")
	elseif ($LEN = 4) OR ($LEN = 5) OR ($LEN = 6)
		cutText $STR $STR 1 ($LEN - 3)
		setVar $STR ($STR & "T")
	elseif ($LEN = 10) OR ($LEN = 11) OR ($LEN = 12)
		cutText $STR $STR 1 ($LEN - 9)
		setVar $STR ($STR & "B")
	elseif ($LEN = 13) OR ($LEN = 14) OR ($LEN = 15)
		cutText $STR $STR 1 ($LEN - 12)
		setVar $STR ($STR & "t")
	elseif ($LEN < 3)
		#Do Nothing
	else
		Echo "***"
		Echo ANSI_15 & "Congrats. You made more cash than anyone in the history of TradeWars"
		Echo "**"
		halt
	end
	return
:PARSE
	getWord $TEMP $XXX[$idx][$idy][$Tot_Shields] 1
	isNumber $tst $XXX[$idx][$idy][$Tot_Shields]
	if ($tst = 0)
    if ($XXX[$idx][$idy][$Tot_Shields] = "---")
      setVar $XXX[$idx][$idy][$Tot_Shields] 0
    end
	end
	getWord $TEMP $XXX[$idx][$idy][$Cols_Ore] 3
	getWord $TEMP $XXX[$idx][$idy][$Cols_Org] 4
	getWord $TEMP $XXX[$idx][$idy][$Cols_Equ] 5
	getWord $TEMP $XXX[$idx][$idy][$Pro_Ore] 6
	getWord $TEMP $XXX[$idx][$idy][$Pro_Org] 7
	getWord $TEMP $XXX[$idx][$idy][$Pro_Equ] 8
	getWord $TEMP $XXX[$idx][$idy][$Tot_Fig] 9
	getWord $TEMP $XXX[$idx][$idy][$Tot_Cred] 10
	replaceText $XXX[$idx][$idy][$Tot_Cred] "---" "-"
	
	setVar $XXX[$idx][$idy][$P_Class] $CLASS
	return
:NUMERIZE
	stripText $STR ","
	replaceText $STR "T" "000"
	replaceText $STR "M" "000000"
	replaceText $STR "B" "000000000"
	return
:PAD
	getLength $STR $LEN
	setVar $Pad ""
	setVar $i 1
	while ($i <= (5 - $LEN))
		setVar $PAD ($PAD & " ")
		add $i 1
	end
	return
:quikstats
	setVar $CURRENT_PROMPT 		"Undefined"
	killtrigger noprompt
	killtrigger prompt1
	killtrigger prompt2
	killtrigger prompt3
	killtrigger prompt4
	killtrigger statlinetrig
	killtrigger getLine2
	setTextTrigger 		prompt1 		:allPrompts 		"(?="
	setTextLineTrigger 	prompt2 		:secondaryPrompts 	"(?)"
	setTextLineTrigger 	statlinetrig 	:statStart 			#179
	setTextTrigger		prompt3         :terraPrompts		"Do you wish to (L)eave or (T)ake Colonists?"
	setTextTrigger		prompt4         :terraPrompts		"How many groups of Colonists do you want to take ("
	send "^Q/"
	pause

	:allPrompts
		getWord currentansiline $checkPrompt 1
		getWord currentline $tempPrompt 1
		getWordPos $checkPrompt $pos ""
		if ($pos > 0)
			setVar $CURRENT_PROMPT $tempPrompt
		end
		setTextLineTrigger prompt1 :allPrompts "(?="
		pause
	:secondaryPrompts
		getWord currentansiline $checkPrompt 1
		getWord currentline $tempPrompt 1
		getWordPos $checkPrompt $pos ""
		if ($pos > 0)
			setVar $CURRENT_PROMPT $tempPrompt
		end
		setTextLineTrigger prompt2 :secondaryPrompts "(?)"
		pause
	:terraPrompts
		killtrigger prompt3
		killtrigger prompt4
		getWord currentansiline $checkPrompt 1
		getWordPos $checkPrompt $pos ""
		if ($pos > 0)
			setVar $CURRENT_PROMPT "Terra"
		end
		setTextTrigger		prompt3         :terraPrompts		"Do you wish to (L)eave or (T)ake Colonists?"
		setTextTrigger		prompt4         :terraPrompts		"How many groups of Colonists do you want to take ("
		pause

	:statStart
		killtrigger prompt1
		killtrigger prompt2
		killtrigger prompt3
		killtrigger prompt4
		killtrigger noprompt
		setVar $stats ""
		setVar $wordy ""

	:statsline
		killtrigger statlinetrig
		killtrigger getLine2
		setVar $line2 CURRENTLINE
		replacetext $line2 #179 " "
		striptext $line2 ","
		setVar $stats $stats & $line2
		getWordPos $line2 $pos "Ship"
		if ($pos > 0)
			goto :gotStats
		else
			setTextLineTrigger getLine2 :statsline
			pause
		end

	:gotStats
		setVar $stats $stats & " @@@"

		setVar $current_word 0
		while ($wordy <> "@@@")
			if ($wordy = "Sect")
				getWord $stats $CURRENT_SECTOR   	($current_word + 1)
			elseif ($wordy = "Turns")
				getWord $stats $TURNS  				($current_word + 1)
			elseif ($wordy = "Creds")
				getWord $stats $CREDITS  			($current_word + 1)
			elseif ($wordy = "Figs")
				getWord $stats $FIGHTERS   			($current_word + 1)
			elseif ($wordy = "Shlds")
				getWord $stats $SHIELDS  			($current_word + 1)
			elseif ($wordy = "Hlds")
				getWord $stats $TOTAL_HOLDS   		($current_word + 1)
			elseif ($wordy = "Ore")
				getWord $stats $ORE_HOLDS    		($current_word + 1)
			elseif ($wordy = "Org")
				getWord $stats $ORGANIC_HOLDS    	($current_word + 1)
			elseif ($wordy = "Equ")
				getWord $stats $EQUIPMENT_HOLDS    	($current_word + 1)
			elseif ($wordy = "Col")
				getWord $stats $COLONIST_HOLDS    	($current_word + 1)
			elseif ($wordy = "Phot")
				getWord $stats $PHOTONS   			($current_word + 1)
			elseif ($wordy = "Armd")
				getWord $stats $ARMIDS   			($current_word + 1)
			elseif ($wordy = "Lmpt")
				getWord $stats $LIMPETS   			($current_word + 1)
			elseif ($wordy = "GTorp")
				getWord $stats $GENESIS  			($current_word + 1)
			elseif ($wordy = "TWarp")
				getWord $stats $TWARP_TYPE  		($current_word + 1)
			elseif ($wordy = "Clks")
				getWord $stats $CLOAKS   			($current_word + 1)
			elseif ($wordy = "Beacns")
				getWord $stats $BEACONS 			($current_word + 1)
			elseif ($wordy = "AtmDt")
				getWord $stats $ATOMIC  			($current_word + 1)
			elseif ($wordy = "Corbo")
				getWord $stats $CORBO   			($current_word + 1)
			elseif ($wordy = "EPrb")
				getWord $stats $EPROBES   			($current_word + 1)
			elseif ($wordy = "MDis")
				getWord $stats $MINE_DISRUPTORS   	($current_word + 1)
			elseif ($wordy = "PsPrb")
				getWord $stats $PSYCHIC_PROBE  		($current_word + 1)
			elseif ($wordy = "PlScn")
				getWord $stats $PLANET_SCANNER  	($current_word + 1)
			elseif ($wordy = "LRS")
				getWord $stats $SCAN_TYPE    		($current_word + 1)
			elseif ($wordy = "Aln")
				getWord $stats $ALIGNMENT    		($current_word + 1)
			elseif ($wordy = "Exp")
				getWord $stats $EXPERIENCE    		($current_word + 1)
			elseif ($wordy = "Corp")
				getWord $stats $CORP   				($current_word + 1)
			elseif ($wordy = "Ship")
				getWord $stats $SHIP_NUMBER   		($current_word + 1)
			end
			add $current_word 1
			getWord $stats $wordy $current_word
		end
	:doneQuikstats
		killtrigger prompt1
		killtrigger prompt2
		killtrigger prompt3
		killtrigger prompt4
		killtrigger statlinetrig
		killtrigger getLine2
return

:SHOW_PLANET
	stripText $XXX[$idx][$idy] " "
	setVar $SHOW FALSE

  if ($CITONLY = TRUE)
  	if ($XXX[$idx][$idy] = "-")
		  setVar $SHOW FALSE
    else
      setVar $SHOW TRUE
	  end
  else
    setVar $SHOW TRUE
  end

	return
:SECTOR_DATA
	setVar $DIST 0
	setVar $SECTOR_DATA_STR ""
	setVar $SECTOR_DATA_STRn ""
	if ($DEST >= 1) AND ($DEST <= SECTORS)
		getDistance $DIST $CURRENT_SECTOR $DEST
		if ($DIST = "-1")
			if ($DEST = $CURRENT_SECTOR)
				setVar $DIST "N/A"
			end
		end
		if ($DEST = $CURRENT_SECTOR)
			setVar $SECTOR_DATA_STR ($SECTOR_DATA_STR & ANSI_14 & "You Are Here!")
			setVar $SECTOR_DATA_STRn ($SECTOR_DATA_STRn & "You Are Here!")
		else
			setVar $SECTOR_DATA_STR ($SECTOR_DATA_STR & ANSI_4 & $DIST & " Hops")
			setVar $SECTOR_DATA_STRn ($SECTOR_DATA_STRn & $DIST & " Hops")
		end
		getSectorParameter $DEST "FIGSEC" $F
		isNumber $tst $F
		if ($tst)
			if ($F <> 0)
				setVar $SECTOR_DATA_STR ($SECTOR_DATA_STR & ANSI_4 & " FIGD")
				setVar $SECTOR_DATA_STRn ($SECTOR_DATA_STRn & " FIGD")
			end
		end
		getSectorParameter $DEST "LIMPSEC" $F
		isNumber $tst $F
		if ($tst)
			if ($F <> 0)
				setVar $SECTOR_DATA_STR ($SECTOR_DATA_STR  & ANSI_4 & " LIMPD")
				setVar $SECTOR_DATA_STRn ($SECTOR_DATA_STRn & " LIMPD")
			end
		end
		getSectorParameter $DEST "MINESEC" $F
		isNumber $tst $F
		if ($tst)
			if ($F <> 0)
				setVar $SECTOR_DATA_STR ($SECTOR_DATA_STR & ANSI_4 & " ARMID")
				setVar $SECTOR_DATA_STRn ($SECTOR_DATA_STRn & " ARMID")
			end
		end
	end
	if ($SECTOR_DATA_STR <> "")
		setVar $SECTOR_DATA_STR (ANSI_12 & "(" & $SECTOR_DATA_STR & ANSI_12 & ")")
		setVar $SECTOR_DATA_STRn ("(" & $SECTOR_DATA_STRn & ")")
		setVar $PAD ""
		setVar $i 1
		getLength $SECTOR_DATA_STRn $LEN1
		getLength $DEST $LEN2
		while ($i <= (55 - ($LEN1 + $LEN2)))
			setVar $PAD ($PAD & " ")
			add $i 1
		end
		setVar $SECTOR_DATA_STR ($PAD & $SECTOR_DATA_STR)
	end
	return