View unanswered posts | View active topics It is currently Thu Mar 28, 2024 3:12 am



Reply to topic  [ 3 posts ] 
 Jump Enter Export Gridder 
Author Message
Gameop
User avatar

Joined: Tue Nov 19, 2002 3:00 am
Posts: 1050
Location: USA
Unread post Jump Enter Export Gridder
Published with permission from Co-Author

J.e.x. Gridder v.41
--No Tech support infered or given, feel free to blow yourself up
---As with most stuff, part's were used with permission via GNU or direct consent of the authors work, those which inspired or were used include:

Dynarri, EP, Lonestar, Mob, and The Bounty Hunter

Happy New Year/Merry Christmas/Thanksgiving/Halloween

When I feel up to it I'll post other scripts I have worked on. You are free to use this script as you desire, with exclusion from any "Script Packages" found elsewhere on this site and all author's cited.
Code:
#Jump Enter Xport Gridder    Mobby+Kaus  2010
#(Quickstats/Xport/Maxfig/Additonal help with main code curtesy of Dynarri @ Navhaz.com)
#Revisions changes @ Bottom of the script
#-- BugTracker: ## xport needs xport check other ship/needs unlim check/still freezing up on validation/halt if cant xport to jp##
#-- Next Todo: Bwarp Routine if shipwarp is higher than 1 and is on a planet/add the sector ztm check in density scan
reqRecording
loadvar $Bot_name
SetVar $RevisionNum ".40"
SetVar $XportSector 0
SetVar $LowData 0
SetVar $ShipNum2 107
SetVar $PlanetNum 0
SetVar $Cycles 0
SetVar $CyclesNum 100
#Can Set The Dodge limits :Public 16/20
SetVar $LowerLimit 12
SetVar $UpperLimit 18
SetVar $Port FALSE
SetVar $Thief FALSE
SetVar $Unlim FALSE
SetVar $ModeChk FALSE
SetVar $DensityPS FALSE
SetVar $Home CURRENTSECTOR
#SetVar $Good True

#gosub :Botme
gosub :quickstats
gosub :prevalidate
#gosub :validate
gosub :planetcheck
Send "'{" $bot_name "} - J.E.X. Gridder Rv" & $RevisionNum & " Now Loading*"
gosub :Dummy
gosub :CN9
gosub :XportCheck
gosub :ClearScreen
gosub :JumpRoutine

#--------------------------------------------------- Main Code -----------------------------------------
#---Start
:MainCode
#--- Pre Jump (Check to see if we should continue)
gosub :quickstats
If ($arraycnt = 0)
Send "'{" $bot_name "} - There are no further available targets from your Xport location, Halting*"
end
If ($quickstats[TURNS] = 0)
   Send "'-Out of turns or I've been torped, Shutting Down*"
   Halt
elseif ($Cycles >= $CyclesNum)
   Send "'{" $bot_name "} - Grid Cycles complete, Shutting Down*"
   Halt
end

#--- Get Random Sector and lets roll
gosub :RandomSec
SetDelayTrigger waiting :waiting 1000
pause

:Waiting
SetTextLineTrigger RightPrompt :Go "Command [TL"
Send "*"
pause

#--- Moving Along (Refuel PreJump Twarp Checks)
:Go
#--- GetDistance/Refuel
SetVar $NeedOre TRUE
SetVar $FuelTotal 0
GetDistance $FuelChk $Home $jumps[$RndSec]
GetDistance $FuelChk2 $targets[$RndSec] $Home
If (($Fuelchk = "-1") OR ($Fuelchk2 = "-1"))
  goto :SkipThis
end
Add $FuelTotal ($Fuelchk + $Fuelchk2)
Multiply $FuelTotal 3 
If ($FuelTotal <= $Quickstats[ORE])
Setvar $NeedOre FALSE
end

:SkipThis
If (($PlanetNum <> 0) AND ($NeedOre = TRUE))
  Send "l " & $PlanetNum & "* t n t 1 * q"
elseif (($PlanetNum = 0) AND ($NeedOre = TRUE))
  Send "p t * * * "
  gosub :quickstats
    If ($Quickstats[ORE] <> $Quickstats[HLDS]
     Send " 'Port appears to be out of fuel, halting."
     halt
   end
end

#--- Check to see if target is right nextdoor
Killalltriggers
getDistance $dist $home $jumps[$RndSec]
if ($dist = 0)
  Echo ANSI_12 "* ZTM Error"
    halt
elseif ($dist = 1)
    Send "m" & $jumps[$RndSec] & "*"
    Echo ANSI_12 "* This is the problem"
    goto :Locked1
  else
    Send "m" & $jumps[$RndSec] & "*"
    waitFor "<Move>"
    killalltriggers
    SetTextTrigger NoWarp :NoWarp "Engage the Autopilot?"
    SetTextTrigger Notlocked :NotLocked "make this jump blind?"
    SetTextTrigger Locked :Locked "shall we engage?"
    Send "y"
  Pause
end

:NoWarp
killalltriggers
send " n n * "
Send "' -Twarp is not enabled on this ship, Halting*"
Halt

:NotLocked
killalltriggers
send " n * "
Send "' -Fighter lock was lost, Halting*"
halt

#--- Lock and Loaded (Twarp JumpSec)
:Locked
killalltriggers
Send "y * "
#Attack sector figs/Say no to a mined sector wait for proper prompt
:Locked1
Send "q q q q z a " & $maxFigAttack & "* "
Waitfor "Command"

#--- JumpSec Stuff
gosub :Density
gosub :SavemeRoutine
add $Cycles 1
Send "'Gridding Sector>> " $targets[$RndSec] " (" & $Cycles & " of " &  $CyclesNum & ")*"
SetVar $TargetMac " m  z" & $targets[$RndSec] & "*  c  *  *  q  q  q  z  a  " & $maxFigAttack & "*  f  z  1  *  z  c  d  z  r  *  x      " & $ShipNum2 & "*  *  @"
Send $TargetMac
waitFor "Average Interval Lag:"
SetSectorParameter $targets[$Rndsec] "FIGSEC" True

#--- Delay to dodge photons (weak to delay torps), can change delay to higher and risk Ship instead (12 / 50)
GetRnd $RandomDelay $LowerLimit $UpperLimit
Setdelaytrigger Emcpu :Emcpu ($RandomDelay*50)
pause

:Emcpu
Killtrigger Emcpu
#--- Plock Detection (Private)
gosub :navpt_plock_drop_detection
If ($Good = False)
    Send "' -Plock or return sector Fighter kill detected, halting"
    halt
end
 
#---Xport/twarp home Rinse and Repeat (Can Blind Warp if no home fig)
SetVar $HomeMac "x      " & $Shipnum1 & "*  *  m" & $Home & "* y y"
Send $HomeMac
:Insert
KillallTriggers

SetVar $Targets[$RndSec] 0
SetVar $Jumps[$RndSec] 0
Goto :MainCode
Halt

#---------------------------------------------------------- Sub Routines ----------------------------------
 
#--- Planet Check
:PlanetCheck
If ($prompt = "Citadel")
:CitHere
Killalltriggers
SetTextlineTrigger HasBwarp :HB "This transporter has"
SetTextlineTrigger NoBwarp :NB "does not have a Transporter"
Send "b"
pause

:HB
Killalltriggers
Getword CURRENTLINE $BwarpRange 7
Echo ANSI_12 "*" $BwarpRange
Send "qq*"
waitFor "Planet #"
  getWord CURRENTLINE $PlanetNum 2
  stripText $PlanetNum "#"
waitfor "Fuel Ore"
  getword CURRENTLINE $OreLevel 6
  Striptext $Orelevel ","
If ($Orelevel < 1000)
  Send "'{" $bot_name "} -Not Enough ore on planet to fuel gridder, twarping instead*"
  SetVar $PlanetNum 0
end
  send "q"
return

:NB
Killalltriggers
Send "nq"
waitFor "Planet #"
  getWord CURRENTLINE $PlanetNum 2
  stripText $PlanetNum "#"
waitfor "Fuel Ore"
  getword CURRENTLINE $OreLevel 6
  Striptext $Orelevel ","
If ($Orelevel < 1000)
  Send "' -Not Enough ore on planet to fuel gridder, twarping instead*"
  SetVar $PlanetNum 0
end
  send "q"
end
return

#--- Dummy Check
:Dummy
#Check to see if Ship is a number
Setvar $ShipNum1 $quickstats[SHIP]
Isnumber $CheckNum $ShipNum2
If ($CheckNum = False) or ($ShipNum2 = 0)
  Send "'-Must Specify A Xport Ship Number.*"
  Halt
#Make sure the xport ship is correct
Elseif ($ShipNum2 <> 0)
  if ($prompt = "Citadel")
    Send "qq"
  end
Send "'-Validating xport ship number**"
Send "x"
Waitfor "----"
:Xprt
SetTextlinetrigger ship :Ship $ShipNum2
Settexttrigger NoShip :Ship2 "ship to beam"
pause

:Ship2
Killalltriggers
Send "'-Ship does not exist, Halting*"
Send "q"
Halt
end

:Ship
KillallTriggers
Getwordpos CURRENTLINE $Xpos $Shipnum2
If ($Xpos >= 2)
cutText CURRENTLINE $line $Xpos 999
  getWord $line $Xtest 1 "%%%"
  Isnumber $XChk $Xtest
  If (($test <> "%%%") AND ($XChk = TRUE))
     goto :XCont
    else
     goto :Xprt
   end
end
:XCont
Getword CURRENTLINE $XportSector 2
If ($XTest = $ShipNum2)
  Echo ANSI_12 "* Verified Ship"
  Send "*"
end
#Check Xport Number
If ($XportSector = 0)
  Send "' Something wrong with $Xport Variable*"
  halt
End
#Check for Twarp and Initial Ore
If ($quickstats[TWARP] < 1) or ($quickstats[ORE] < 50)
  Send "' -Gridder is either missing Twarp or Ore to start script.*"
   Halt
#Are we carrying Photons?
elseif ($quickstats[PHOT] <> 0)
   Send "'-Gridder has torps on board, you trying to get me killed?*"
   halt
#Is There a fig in the home sector?
elseif ($PlanetNum = 0)
   SetVar $Port TRUE
send " dz* "
waitFor "<Re-Display>"
waitFor "Command [TL="
elseif (SECTOR.FIGS.QUANTITY[$Home] > 0)
    if ((SECTOR.FIGS.OWNER[$Home] <> "belong to your Corp") AND (SECTOR.FIGS.OWNER[$Home] <> "yours"))
        halt
    end
else
    send " f z 1 * z c d * "
end
If (($Planetnum = 0) AND (PORT.BUYFUEL[$Home] = TRUE))
  Send "' -No planet number found and no fuel port in home sector, halting..*"
  halt
elseif (($Planetnum = 0) AND (PORT.BUYFUEL[$Home] = FALSE) AND (PORT.EXISTS[$Home]))
  Send "'-No planet number found, guess well port and twarp then*"
end
return

#--- Targetting Sector Routine (Mobby)
:JumpRoutine
Send "'-Creating Targetting Array, Please Stand By: *"
Setvar $RandomCounter 1
setarray $targets SECTORS
setarray $jumps SECTORS
setvar $arraycnt 0
setvar $xportsec $XportSector
setvar $xportmax $max_xport
setVar $increment ((SECTORS - 11) / 10)
setVar $coefficient 1
setVar $i 11
echo ANSI_15 "*Finding J.E.X. Grid Targets*"
echo ANSI_15 "1%          100%" #27  "[14D"

while ($i <= SECTORS)
#Progress Bar (embedded/EP)
  if ($i > ($coefficient * $increment))
   echo ANSI_12 "|"
   add $coefficient 1
  end
getsectorparameter $i "FIGSEC" $figged
  if ($figged > 0)
  goto :check_next_target_idx
  end

setVar $jump_point 0
setVar $adj_idx 1
while ($adj_idx <= SECTOR.WARPINCOUNT[$i])
   setVar $adj_sect SECTOR.WARPSIN[$i][$adj_idx]
   getSectorParameter $adj_sect "FIGSEC" $figged
     if ($figged > 0)
      setVar $jump_point $adj_sect
     end
   add $adj_idx 1
end

if ($jump_point <= 10)
goto :check_next_target_idx
end

getDistance $dist_to   $i $xportsec
getDistance $dist_from $xportsec $i
if (($dist_to > $xportmax) OR ($dist_from > $xportmax))
goto :check_next_target_idx
end

add $arraycnt 1
setVar $targets[$arraycnt] $i
setVar $jumps[$arraycnt] $jump_point

:check_next_target_idx
add $i 1
end
Return

#--- Bot Command Routing (MOM Inspired)
:BotMe
loadVar $Parm1
Lowercase $Parm1
If ($Parm1 = "safe")
    #Default Mode Setting
    goto :BotVariable
  elseif ($Parm1 = "pas")
   #Some Variable Setting
    Send " 'Not a available rv." & $RevisionNum & "command.*"
    halt
  elseif ($Parm1 = "agg")
    #Some Variable Setting
    Send " 'Not a available rv." & $RevisionNum & "command.*"
     halt
   elseif ($Parm1 = "help")
   Send " '*"
   Send "{" $bot_name "} -Jump Enter Xport Gridder Rv" & $RevisionNum & "*"
   Send " - format: jgrid [mode] {s:##} {c:##} {d:#/#} *"
   Send " -*"
   Send " - [Modes]   {pas}sive,{safe},{agg}ressive *"
#   Send " - aggressive - grid into most targets [avoids planets]*"
#   Send " - passive - passive surround jumppoints [uses safe method]*"
   Send " - safe - avoid sectors with limps,navhaz, or anomolies[default]*"
   Send " -*"
   Send " - {s:x} xport ship number [required]*"
   Send " - {c:x} cycles to run the gridder [default: 1 cycle]*"
   Send " - {d:x/x} config lower/upper limit xport delay [default 16/20]**"
#   Send " - {t:x,x,x} targetable list variable [t:1,2,3,etc] **"
   SetVar $Parm1 "---===---"
   SaveVar $Parm1
  halt
Else
  goto :BotVariable
halt
end

:BotVariable
loadVar $user_command_line
lowercase $user_command_line
getWordPos $user_command_line $pos "c:"
if ($pos > 0)
  cutText $user_command_line $line $pos 999
  replaceText $line ":" " "
  getWord $line $test 2 "%%%"
  Isnumber $CheckNum $test
  If (($test <> "%%%") AND ($CheckNum = TRUE))
    SetVar $CyclesNum $test
    SetVar $ModeChk TRUE
   end
end

getWordPos $user_command_line $pos2 "s:"
if ($pos2 > 0)
  cutText $user_command_line $line2 $pos2 999
  replaceText $line2 ":" " "
  getWord $line2 $test2 2 "%%%"
  Isnumber $CheckNum2 $test2
    If (($test2 <> "%%%") AND ($CheckNum2 = TRUE))
      SetVar $Shipnum2 $test2
      SetVar $ModeChk TRUE
   end
end

getWordPos $user_command_line $pos3 "d:"
if ($pos3 > 0)
  cutText $user_command_line $line3 $pos3 999
  replaceText $line3 ":" " "
  replaceText $line3 "/" " "
  getWord $line3 $test3 2 "%%%"
  getWord $line3 $test31 3 "%%%"
  Isnumber $CheckNum3 $test3
  Isnumber $CheckNum31 $test31
    If (($test2 <> "%%%") AND ($CheckNum3 = TRUE) AND ($CheckNum31 = TRUE))
      SetVar $LowerLimit $test3
      SetVar $UpperLimit $test31
      SetVar $ModeChk TRUE
   end
end

If ($Modechk <> TRUE)
  Send " '*"
  Send "{" $bot_name "} -Not a recognised J.E.X. Grid Rv" & $RevisionNum & " command*"
  Send "Jgrid {help} for further assistance. **"
  Halt
end
SetVar $command "--==--"
SaveVar $command
SetVar $user_command_line "---===---"
SaveVar $user_command_line
SetVar $Parm1 "---===---"
SaveVar $Parm1
Return

#--- Prevalidate (I.e. Planet/Sector/Cit Check)
:Prevalidate
send #145
waitFor #145
setVar $currentline CURRENTLINE
stripText $currentline #8
stripText $currentline #145
getWord $currentline $prompt 1
if (($prompt <> "Citadel") AND ($prompt <> "Command"))
    send "'{" $bot_name "} -  Jgrid - Must run from the Citadel or Command prompt!*"
    halt
end
Return

#--- Validate/AntiTheft
:Validate
#Stardock for target game
If (STARDOCK <> 10838)
Setvar $Thief TRUE
end
#--- Check Time expiration
send "ctq"
setTextLineTrigger ctq_trigger :ctq ", "
pause

:ctq
Killalltriggers
getWord CURRENTLINE $month 4
getWord CURRENTLINE $day   5
Striptext $day ","
getWord CURRENTLINE $year  6
#Set Year
if ($year <> "2022")
SetVar $Thief TRUE
#Months we want them to use it
elseif ($month <> "Jul")
SetVar $Thief TRUE
#Day if applicable
#elseif ($day <> "01")
#SetVar $Thief TRUE
End

#--- Enable these for .CTS handout
If ($Thief = TRUE)
echo ansi_12 "**This Script is no longer valid, Please contact Kaus  for a new version..*"
  halt
end

#---- Disclaimer
echo #27 & "[1B" & #27 & "[15D" & #27 & "[1;5;35;44m!!!WARNING!!!" #27 "[0;1;37;40m"
Echo ANSI_12 "*Script is set to expire by" ANSI_15 " August 1st, 2010" ANSI_12 ", use at your own risk."
Echo ANSI_10 "*Script will start in:"
Echo ANSI_10 "*3     " #27 "[5D"
setVar $Timeleft 3
:Countdown
SetDelayTrigger Timeleft :TimeLeft 350
Pause

:Timeleft
Subtract $Timeleft 1
If ($Timeleft = 2)
   echo ANSI_11 " 2"
   goto :countdown
  Elseif ($TimeLeft = 1)
    echo ANSI_6  " 1"
    goto :countdown
     Elseif ($Timeleft = 0)
Return
end
Halt

#---Saveme Triggers
:SavemeRoutine
SetTextTrigger Saveme1 :Saveme "An Interdictor Generator in this sector holds you fast!"
SetTextTrigger Saveme2 :Saveme "The Quasar Cannon on"
SetTextTrigger Saveme3 :Saveme "is powering up weapons systems!"
setTextTrigger Saveme5 :Saveme "You do not have enough Fuel Ore to make the jump."
setTextTrigger Saveme6 :Saveme "Engage the Autopilot?"
setTextTrigger Saveme7 :Saveme "launched a P-Missile in sector"
setTextTrigger Saveme8 :Saveme "You don't have enough turns left."
setTextTrigger Saveme9 :Saveme "You attempt to retreat but are held fast by an Interdictor Generator."
setTextTrigger Saveme10 :Saveme "[Pause]"
setTextTrigger Saveme11 :Saveme "has just materialized from the void!"
setTextTrigger Saveme12 :Saveme "You have 0 turns left"
SetDelayTrigger Saveme13 :timeout1 10000
Return
pause

#---Saveme Routine (MOM Inspired)
:SaveMe
killAllTriggers
gosub :quickstats
setVar $figstodeploy 1
setVar $savetarget CURRENTSECTOR
setvar $SaveMac "q q q r * * * *"
send $SaveMac
gosub :deployfigs
Send "'" & $Savetarget & "=saveme*"
     
:waitforhelp
    setTextLineTrigger friendlyplanet :friendlyplanet "Saveme script activated - Planet "
    setDelayTrigger timeout :timeout 30000
pause
     
:timeout
killalltriggers
send "' -30 seconds after save call, script halted.*"
halt


:timeout1
killalltriggers
send "' -Ut Oh, somethign is seriously fubar'd with my TA, please saveme*"
goto :Saveme
halt

:friendlyplanet
  killalltriggers
  getText CURRENTLINE $planet1 "Saveme script activated - Planet " " to "
  send "l " & $planet1 & "* c 'Gridder Safe on Planet #" & $planet1 & "*"
halt

:deployfigs
    if ((CURRENTSECTOR <= 10) or (CURRENTSECTOR  = STARDOCK))
        send "'Can't deploy figs in fed*"
        return
    end
    send "a y y 9999* F"
    setTextLineTrigger nocontrol :nocontrol "These fighters are not under your control."
    setTextLineTrigger abletodeploy :abletodeploy "fighters available."
    pause

:nocontrol
killalltriggers
send "'We don't control the figs in this sector!*"
  loadvar $password
  send "q y * t* * *" $password "*    *    *       za9999*   z*   f 1 c d *"
return

:abletodeploy
   killalltriggers
   getWord CURRENTLINE $figsavailable 3
   striptext $figsavailable ","
if ($figsavailable = 0)
  send "0* ZC D* 'I have no figs to deploy!*"
    else
  send $figstodeploy & "* ZC D* '" & $figstodeploy & " figs deployed*"
end
Return
halt

#----Clear Screen
:ClearScreen
echo #27 & "[2J"
return

#---CN9 Settings
:CN9
Send "Cn"
setTextLineTrigger cnAni :CNAni "Animation display"
  pause
:CNAni
GetWord CURRENTLINE $Display 5
  If ($Display = "On")
   Send "n2qq"
  Else
   Send "qq"
end
Send "Cn"
setTextLineTrigger cnKeys :cnKeys " Abort display"
  pause
:cnKeys
GetWord CURRENTLINE $Display1 7
  If ($Display1 = "ALL")
   Send "n9qq"
  Else
   Send "qq"
end
return

#---Navigation Plock Detector Removed for Public Release
:navpt_plock_drop_detection
:navpoint_nogood
setVar $good FALSE
pause

:navpoint_end
killTrigger planet_hunt
killtrigger navpt_end
return

#--- Density Passive Routine(Mobby)
:Density
send "s d"
waitFor "Relative Density Scan"
waitFor "Command"
###Add Check for warpsec
If ($DensityPS = True)
   Goto :PassiveSurround
  elseif ((SECTOR.ANOMOLY[$targets[$RndSec]] <> 0) OR (SECTOR.DENSITY[$targets[$RndSec]] > 490) OR (SECTOR.NAVHAZ[$targets[$RndSec]] <> 0))
    Send "'Unusual density detected, gridder is skipping sector " & $targets[$RndSec] & "*"
    Send "m " & $Home & " * y y "
    goto :Insert
end
Return


:PassiveSurround
setVar $i 1
while ($i <= SECTOR.WARPCOUNT[CURRENTSECTOR])
setvar $tarsec SECTOR.WARPS[CURRENTSECTOR][$i]

if (SECTOR.DENSITY[$tarsec] = 0) or (SECTOR.DENSITY[$tarsec] = 100) and (SECTOR.ANOMOLY[$tarsec] = FALSE)
   echo ANSI_12 "*" $tarsec ANSI_11 " - looks safe*"
   goto :next_sec
else
   goto :whynogo
end

:whynogo
if (SECTOR.DENSITY[$tarsec] <> 0) or (SECTOR.DENSITY[$tarsec] <> 100)
  echo ANSI_11 "*" $tarsec " has a questionable density*"
end

if (SECTOR.ANOMOLY[$tarsec] = 1)
  echo ANSI_12 $tarsec " also has an anomoly*"
end

:next_sec
add $i 1
end
Return

#--- RandomSec
:RandomSec
GetRnd $RndSec 1 $arraycnt
If (($Jumps[$Rndsec] = CURRENTSECTOR) or ($Jumps[$RndSec] = 0) or ($Targets[$RndSec] = STARDOCK) or ($Jumps[$RndSec] = STARDOCK))
  Add $RandomCounter 1
     If ($RandomCounter = 10)
     Add $LowData 1
      If ($LowData = 1)
       Send "'-Low Target Sector Data, Recreating Target Array*"
       end
     KillallTriggers
       If ($LowData = 2)
         Send "'{" $bot_name "} -Low Target Sector Data, script Halted*"
           Halt
         end
     goto :JumpRoutine
   end
  goto :Randomsec
end
Return

# Get fig wave and xport range
:XportCheck
send "  c  ;q  " 
waitFor "Max Figs Per Attack:" 
getWord CURRENTLINE $maxFigAttack 5
waitFor "Transport Range: "
getWord CURRENTLINE $max_xport 6
if ($maxFigAttack > $quickstats[FIGS])
    setVar $maxFigAttack $quickstats[FIGS]
end
return

#--- Dnyarri's Quick Stats
:quickstats
     killtrigger statlinetrig
     setVar $stats ""
     setTextLineTrigger statlinetrig :statsline #179
     send "/"
pause

:statsline
     killtrigger statlinetrig
     setVar $line CURRENTLINE
     replacetext $line #179 " "
     striptext $line ","
     setVar $stats $stats & $line
     getWordPos $line $pos "Ship"
     if ($pos > 0)
          goto :gotStats
     else
          setTextLineTrigger statlinetrig :statsline
     end
pause

:gotStats
     setVar $quickstats[SECT] 0
     setVar $quickstats[TURNS] 0
     setVar $quickstats[CREDS] 0
     setVar $quickstats[FIGS] 0
     setVar $quickstats[SHLDS] 0
     setVar $quickstats[HLDS] 0
     setVar $quickstats[ORE] 0
     setVar $quickstats[ORG] 0
     setVar $quickstats[EQU] 0
     setVar $quickstats[COL] 0
     setVar $quickstats[PHOT] 0
     setVar $quickstats[ARMD] 0
     setVar $quickstats[LMPT] 0
     setVar $quickstats[GTORP] 0
     setVar $quickstats[TWARP] 0
     setVar $quickstats[CLKS] 0
     setVar $quickstats[BEACNS] 0
     setVar $quickstats[ATMDT] 0
     setVar $quickstats[CRBO] 0
     setVar $quickstats[EPRB] 0
     setVar $quickstats[MDIS] 0
     setVar $quickstats[PSPRB] "NO"
     setVar $quickstats[PLSCN] "NO"
     setVar $quickstats[LRS] "NONE"
     setVar $quickstats[ALN] 0
     setVar $quickstats[EXP] 0
     setVar $quickstats[CORP] 0
     setVar $quickstats[SHIP] 0
     setVar $quickstats[TYPE] 0
     setVar $stats $stats & " @@@"
     upperCase $stats
     setVar $current_word 0
     setVar $wordy ""
     while ($wordy <> "@@@")
          if ($wordy = "SECT")
               getWord $stats $quickstats[SECT]   ($current_word + 1)
          elseif ($wordy = "TURNS")
               getWord $stats $quickstats[TURNS]  ($current_word + 1)
          elseif ($wordy = "CREDS")
               getWord $stats $quickstats[CREDS]  ($current_word + 1)
          elseif ($wordy = "FIGS")
               getWord $stats $quickstats[FIGS]   ($current_word + 1)
          elseif ($wordy = "SHLDS")
               getWord $stats $quickstats[SHLDS]  ($current_word + 1)
          elseif ($wordy = "HLDS")
               getWord $stats $quickstats[HLDS]   ($current_word + 1)
          elseif ($wordy = "ORE")
               getWord $stats $quickstats[ORE]    ($current_word + 1)
          elseif ($wordy = "ORG")
               getWord $stats $quickstats[ORG]    ($current_word + 1)
          elseif ($wordy = "EQU")
               getWord $stats $quickstats[EQU]    ($current_word + 1)
          elseif ($wordy = "COL")
               getWord $stats $quickstats[COL]    ($current_word + 1)
          elseif ($wordy = "PHOT")
               getWord $stats $quickstats[PHOT]   ($current_word + 1)
          elseif ($wordy = "ARMD")
               getWord $stats $quickstats[ARMD]   ($current_word + 1)
          elseif ($wordy = "LMPT")
               getWord $stats $quickstats[LMPT]   ($current_word + 1)
          elseif ($wordy = "GTORP")
               getWord $stats $quickstats[GTORP]  ($current_word + 1)
          elseif ($wordy = "TWARP")
               getWord $stats $quickstats[TWARP]  ($current_word + 1)
          elseif ($wordy = "CLKS")
               getWord $stats $quickstats[CLKS]   ($current_word + 1)
          elseif ($wordy = "BEACNS")
               getWord $stats $quickstats[BEACNS] ($current_word + 1)
          elseif ($wordy = "ATMDT")
               getWord $stats $quickstats[ATMDT]  ($current_word + 1)
          elseif ($wordy = "CRBO")
               getWord $stats $quickstats[CRBO]   ($current_word + 1)
          elseif ($wordy = "EPRB")
               getWord $stats $quickstats[EPRB]   ($current_word + 1)
          elseif ($wordy = "MDIS")
               getWord $stats $quickstats[MDIS]   ($current_word + 1)
          elseif ($wordy = "PSPRB")
               getWord $stats $quickstats[PSPRB]  ($current_word + 1)
          elseif ($wordy = "PLSCN")
               getWord $stats $quickstats[PLSCN]  ($current_word + 1)
          elseif ($wordy = "LRS")
               getWord $stats $quickstats[LRS]    ($current_word + 1)
          elseif ($wordy = "ALN")
               getWord $stats $quickstats[ALN]    ($current_word + 1)
          elseif ($wordy = "EXP")
               getWord $stats $quickstats[EXP]    ($current_word + 1)
          elseif ($wordy = "CORP")
               getWord $stats $quickstats[CORP]   ($current_word + 1)
          elseif ($wordy = "SHIP")
               getWord $stats $quickstats[SHIP]   ($current_word + 1)
               getWord $stats $quickstats[TYPE]   ($current_word + 2)
          end
          add $current_word 1
          getWord $stats $wordy $current_word
     end
Return 

#-----------------------------------------------------------Revisions and 2do----------------------------------------------------
#Intentions  -  Automated/Bottable 2 Ship Gridder
# - SD Check/Passive Surround w/xport,
# - Attempt to Packet the enter/kill/xport using plots,
# - Dscan Prior to Surround if high holo and report to subcomm
##
#R.01 -R.37  Layout for future modules, Added XportCheck (Rewritten for simplicity), Mobby Jumpsec Logix added,
## Getrnd Logic, Mobs Denisty Scan Logix added - Added Movement/Attack/Xport
## Refined movement/Anti-Plock(Sing)/Futher Refinements/Fixed to allow for further rnd of delay using a 50ms chuck
##Refined Code/NavpointRoutine/Added&Modified EP's Ansi Progress Bar/Clear Screen/CN9 Checks
##Added Saveme Routines from ArgGridder (Need to be modified)/Basic Bot Help Screen/ Single Density Routine
##Flavor Text/Basic Bot Commands/Added More Safties (Turns/Cycles)/Commented Script for readability
##Updated Saveme Routine/RandomCode Updates/Bot Comms/Planet Check/Fixed Anti Theft
##Rewrote planet check moved to prevalidation/Rerewrote planet check/ Added further flavor text
##Removed dependance on Xport Ship being same sector Gridder can be run from any sector
##Calculates for Xport Length vs. Defined Xport Sector as found in Dummy Check
##Fixed TarSec Routine(Forgot a Return)/Fixed Xport Checker(needed wordpos)/Add Getdistance Routine
##Cleaned up Misc Code/Fixed getdistance/Fixed Xport/Fixed Twarp issue/Misc fixes to other textlinetriggers
##Fixed Botcommand defaults to safe now/cleaned up misc code/possible fix for bad ztm warps/misc code updates
##Refixed Xport issue wordpos/added check for ore/removed text for bad ztm/Added a  @ to attack
##Added spaces to return macro/Added Delay BotParm/Fixed Move next sec routine

_________________
Dark Dominion TWGS
Telnet://twgs.darkworlds.org:23
ICQ#31380757, -=English 101 pwns me=-
"This one claims to have been playing since 1993 and didn't know upgrading a port would raise his alignment."


Last edited by Kaus on Mon Nov 26, 2012 10:29 am, edited 2 times in total.



Sun Nov 25, 2012 10:31 pm
Profile ICQ
Boo! inc.
User avatar

Joined: Sat Oct 09, 2004 2:00 am
Posts: 865
Location: USA
Unread post Re: Jump Enter Export Gridder
Enjoy kiddo's....MEERRRYYY CHRRIISSTTMASSSS!!! HO HO HO

_________________
“The object of war is not to die for your corp but to make the other bastard die for his.”

Boo! inc.


Mon Nov 26, 2012 7:29 am
Profile
Commander
User avatar

Joined: Fri Jun 09, 2006 2:00 am
Posts: 1396
Location: Canada
Unread post Re: Jump Enter Export Gridder
wow cool. you guys finished it, can't wait to try it out. I don't think I deserve credit though, but it's appreciated.


Lone

_________________
----------------------------
-= QUANTUM Computing 101: 15 = 3 x 5 ... 48% of the time.
-= There are 10 types of people in the world: Those that understand Binary and those who do not
-= If Oil is made from Dinosaurs, and Plastic is made from Oil... are plastic Dinosaurs made from real Dinosaurs?
-= I like to keep my friends and my enemies rich, and wait to see which is which - Tony Stark (R.I.P.)


Mon Nov 26, 2012 9:19 am
Profile ICQ YIM
Display posts from previous:  Sort by  
Reply to topic   [ 3 posts ] 

Who is online

Users browsing this forum: No registered users and 18 guests


You cannot post new topics in this forum
You cannot reply to topics in this forum
You cannot edit your posts in this forum
You cannot delete your posts in this forum
You cannot post attachments in this forum

Search for:
Jump to:  
cron
Powered by phpBB © 2000, 2002, 2005, 2007 phpBB Group.
Designed by STSoftware.